; NewIcons 4.0 Installer Script
; $Ver: 40.1 (17-Aug-97)
; Written by Phil Vedovatti
; Brought to you by Team NewIcons

(set @default-dest "SYS:C")

(set #wrongversion
(cat "You have an old version of the program 'Installer' "
     "on your Amiga!\n\nThis installation needs at least Installer 42.9,\n\n"
     "available on Aminet (ftp.wustl.edu)"))

(set #bad-kick
   (cat "\n\nSorry! You must have Workbench 2.0 or"
        "higher to to use this package."))

(set #no-classact
   (cat "\nHmmm!  You don't seem to have the ClassAct 2.0"
        "\nGUI system installed.  You can obtain the"
        "\nlatest ClassAct classes via ftp on the"
        "\nInternet at: \n\n ftp.warped.com/pub/amiga/classact/."
        "\n\n Installation aborted!"))

(set #Help-classact
   (cat "\nThis package requires ClassAct 2.0, which does not"
        "\nappear to be installed on your system.  Select"
        "\n'Continue' to intall the program anyway, or select"
        "\n'Abort' to end the installation."))

(set #hello-message
   (cat "\n\nThank you for trying NewIcons 4, the revolutionary"
        "\nGraphical User Interface system for the Amiga."
        "\nPlease read the documentation to get the most out"
        "\nof this package.  Nothing will be deleted from your"
        "\nsystem with this installation program.  Your old WB"
        "\nicons will still be there, even though it won't look"
        "\nlike it on your screen.  If you don't understand any"
        "\npart of the installation, click on the \"Help\" gadget"
        "\nfound throughout the installation for more information."
        "\n\nCLICK TO PROCEED"))

(set #hello-NIuser
   (cat "\nGreetings current NewIcons user!\n"
        "\nThanks for your continued support for NewIcons."
        "\nPlease check the documentation for the new changes"
        "\nto this version.  NewIcons 4 is faster, more user"
        "\nfriendly, and sports a new 32 color iconset for you"
        "\npower users.  "
        "\n\nIf you don't understand any part of the installation,"
        "\nclick on the \"Help\" gadget found throughout the"
        "\ninstallation for more information."
        "\n\nCLICK TO PROCEED"))

(set #welcome-message
   (cat "\nThe NewIcons System ©1993-1997 Team NewIcons"))
(set #install-which
   (cat "\nWhich part(s) of the NewIcons System would"
        "\nyou like to install onto your hard drive?\n"))

(set #MEorHE
   (cat "\nYour computer setup allows for installation of one"
        "\nof the more advanced versions of the newicons.library."
        "\n\nWhich version would you prefer to install"
        "\non your system?"
        "\n(Click on 'Help' if you're not sure which to choose.)\n"))

(set #MEHEhelp
   (cat "\n\nThe Middle-End library supports an optional dithering"
        "\nmode, useful if you use a Workbench screenmode with"
        "\nfewer colors (e.g. 16 colors or less), and does not"
        "\nsupport the graphics card RTG mode."
        "\n\nThe High End library has the dithering code removed"
        "\nfor additional icon-loading speed, and has an optional"
        "\nRTG mode if you have a graphics card.  If you run"
        "\nyour Workbench in 32 or more colors (AGA), or have a"
        "\ngraphics card, installation of the High End library"
        "\nis recommended."))

(set #install-library
   (cat "\n\nInstalling NewIcon.library to LIBS:."))

(set #install-library-help
   (cat "\n\nThis library is required to use NewIcons."))

(set #install-newicons
   (cat "\n\nCopying the NewIcons executable file"
        "\n and support files to C:"))

(set #install-newicons-help
   (cat "\n\nThis section installs NewIcons, InjectBrush"
        "\nPatchOpenWB and ShowNI to your C: directory."))

(set #installdrawers
   (cat "\nThe Update Drawers utility allows you to select"
        "\nand install the drawer image of your choice to"
        "\nall subdirectories in a drawer or partition.\n"
        "\nWould you like to update some partitions or"
        "\nsubdirectories with a new drawer image now?"))

(set #insdraw-help
   (cat "\nThis part of the installer will execute the"
        "\nUpdate drawers utility, allowing you to install"
        "\nNewIcon drawer images to the drawers and sub-"
        "\ndrawers of the partition or drawer you select."
        "\n\nIt will add a NewIcon drawer image to ALL the"
        "\ndrawer icons in that selected partition or drawer."
        "\n\nIf you are unsure that you want to do this,"
        "\nskip this portion of the installation by"
        "\nselecting NO."))

(set #selectdir
   (cat "Select a drawer or partition.  The default drawer"
        "\nimage icon will be installed to all subdirectories"
        "\nof your selection.  The icon of the actual drawer"
        "\nor partition you selected will not be affected."))

(set #seldirhelp
   (cat "\nThis part of the installer will let you install"
        "\nthe default drawer NewIcon image to all of the"
        "\nsubdirectories of the drawer or partition you"
        "\nhave selected."
        "\n\nThe actual icon of the selected item (the top"
        "\ndrawer or partition) will not be affected."
        "\n\nIf you are unsure that you want to do this,"
        "\nskip this portion of the installation by leaving"
        "\nthe selection entry blank, and click 'Proceed'."))

(set #moredrawers
   (cat "\n\nWould you like to install more drawer images?"
        "\n\nSelect YES to select another drawer or partition."
        "\n\nSelect NO to continue with the remainder of the"
        "\nNewIcons System installation."))

(set #moredraw-help
   (cat "\nSelect YES if you would like to add more default"
        "\ndrawer images to all the subdirectories of another"
        "\npartition or drawer."
        "\n\nSelect NO to move on with the remainder of the"
        "\ninstallation process."))

(set #installdisk
   (cat "\nThis part of the installer lets you customize the"
        "\ndisk images that appear on the Workbench for your"
        "\nhard drive partitions and other available devices."
        "\nYou will be given several image choices to choose"
        "\nfrom.  Would you like to do this now?"))

(set #insdisk-help
   (cat "\nIf you select 'Yes', you will be presented with"
        "\na requester asking you which device you would"
        "\nlike to update with a new disk icon image.  Once"
        "\nyou have selected the device to be updated, you"
        "\nwill be given a choice from several icon images"
        "\nto select as the disk icon image for that chosen"
        "\n\ndevice."
        "\n\n If you do not want to update your disk icons"
        "\nwith a new image now, select 'No' instead."))

(set #selectdisk
   (cat "Select a hard disk partition or device.  You will"
        "\nthen be given a choice of icons to select as the"
        "\ndisk icon for that device. All subdirectories,"
        "\files, and other device icons will not be affected."))

(set #seldiskhelp
   (cat "\nThis part of the installer will let you install"
        "\nan icon image to be used for the disk icon of"
        "\na selected device (hard disk partition, floppy"
        "\ndisk, ZIP disks, etc."
        "\n\nNo files other than the 'disk.info' file for"
        "\nthat device will be updated."
        "\n\nIf you are unsure that you want to do this,"
        "\nskip this portion of the installation by leaving"
        "\nthe selection entry blank, and click 'Proceed'."))

(set #moredisks
   (cat "\n\nWould you like to install more disk images?"
        "\n\nSelect YES to select another device."
        "\n\nSelect NO to continue with the remainder of the"
        "\nNewIcons System installation."))

(set #moredisk-help
   (cat "\nSelect YES if you would like to add more default"
        "\ndisk images to selected disk devices."
        "\n\nSelect NO to move on with the remainder of the"
        "\ninstallation process."))

(set #install-icons
   (cat "\n\nInstalling the NewIcons icon images to your"
        "\nSYS: partition."
        "\n\nYour old icons will NOT be removed."
        "\n\nNOTE: make sure you have the standard Amiga 'list'"
        "\ncommand in your command path before proceeding."
        "\n\nInstalling may take some time...patience."))

(set #install-icons-help
   (cat "\n\nThe new icon images will be embedded in"
        "\nthe tool types of your existing .info"
        "\nfiles.  The tooltype lines will be"
        "\ninvisible once NewIcons is running"
        "\nso operation will be totally transparent"
        "\nto the user."))

(set #tools-dest
   (cat "\nWhich drawer would you like the NewIcon"
        "\nmanipulation utilities to be installed?"
        "\nA drawer will NOT be created."))

(set #install-prefs
   (cat "\nInstalling NewIconsPrefs to your"
        "\nSys:prefs directory."))

(set #install-prefs-help
   (cat "\nUse this program to configure NewIcons!"))


(set #startup-change
   (cat "\nNewIcons V3.0 and above requires this line in"
        "\nyour user startup to launch it.  Shall I add"
        "\n\n'Run <NIL: >NIL: c:NewIcons'"
        "\n\nto your S:user-startup file?"
        "\n\n(You may need to remove the old line manually"
        "\nif you are updating and didn't originally"
        "\ninstall NewIcons using the Installer utility.)"))

(set #install-deficons
   (cat "\n\nInstalling the DefIcons daemon to your"
        "\nC: directory, and copying default icons"
        "\nto your Envarc:sys directory."))

(set #install-deficons-help
   (cat "\nThis sections installs the Deficons program"
        "\nand copies the required def_icons to your"
        "\nENVARC: directory."))

(set #move-olddefs-dir
   (cat "The installer will move your old default"
        "\nicons to another location for safe keeping."
        "\nWhere would you like me to create a directory"
        "\nto put them in?"))

(set #move-olddefs-help
   (cat "\nThis section copies your old default icons to"
        "\na safe place instead of overwriting them."
        "\nShould you wish to deinstall Deficons, you"
        "\nWill have them available to restore."))

(set #move-olddefs
   (cat "Moving your old default icons to \n"
        destdir))

(set #install-envarc
   (cat "\nCopying the default icons and brainfile"
        "\nto ENVARC: so DefIcons can use them.\n"))

(set #install-envarc-help
   (cat "\n\nThis section installs the icons that DefIcons"
        "\nwill use to display icon images for files that"
        "\ndon't have icons already attached to them."))

(set #startup-deficons
   (cat "\n\nAdding a line to your S:user-Startup file"
        "\nto launch DefIcons whenever the system"
        "\nis booted up."))

(set #powb-message
   (cat "\n\nIf you have installed NewIcons, you must "
           "add a line to your S:Startup-Sequence:\n\n"
           "C:PatchOpenWB\n"
           "\nto fix a bug in the 3.x operating system!"
           "\n\n Make sure to place the line after Setpatch"
           "\nand before IPrefs."
           "\n\nMCP users and MCX users using the PatchOpenWB"
           "\noption can skip adding this line."))

(set #docs-dest
   (cat "Where would you like the NewIcons Documentation"
        "\nGuide to be installed?"))


(set #incdir
   (cat "Where would you like the include files to go?"))

(set #srcdir
   (cat "Where would you like the example source code"
	"\nto be installed?"))

(set #autoddir
   (cat "Where would you like the Autodoc material"
	"\n to be copied to?"))

(set #emoddir
   (cat "Where would you like the E modules to be"
        "\ninstalled to?"))

(set #exit-message
   (cat "\nPlease reboot your system to fully activate\n"
        "the new NewIcons System, then set your"
        "\npreferences with the Prefs program."
        "\n\n\nWe hope you enjoy this package!"
        "\n\n\nCheck out the NewIcons Web Page at"
        "\nhttp://www.amiganet.org/NewIcons/"))



; ------------------------------------
; Check Installer & Kickstart Version
; ------------------------------------

(if (< @installer-version 2752521)
  (
    (message #wrongversion (all))
    (exit (quiet))
  )
)

 (if (< (getversion "LIBS:version.library") (* 37 65536))
        (abort #bad-kick)
 )


; ------------------------------
; Check if ClassAct 2.0 installed
; ------------------------------

(if (< (getversion "libs:window.class") (* 42 65536))
   (abort #no-classact)
)

; ------------------------------
; Greetings, user!
; ------------------------------

(set NIon (run "/c/isnirunning" (safe)))
     (if (> NIon 0)
        (message #hello-NIuser (all))
        (message #hello-message (all))
     )

(welcome #welcome-message)


; ------------------------------
; What should I install?
; ------------------------------

(complete 0)
(set InstallOpt
      (askoptions (prompt #install-which)
                  (help @askoptions-help)
                  (choices "NewIcons" "DefIcons" "New 32 Color Icon Set" "Documentation" "Developer Data")
                  (default 15)
      )
)


; ------------------------------
; Install NewIcon.library
; ------------------------------

(complete 10)

  (if (OR (patmatch (database "cpu") "68000|68010")

        (< (getversion "LIBS:version.library") (* 39 65536)
       )
      )

      (copylib
           (source "/libs/LE/newicon.library")
           (dest "libs:")
           (prompt #install-library)
           (help #install-library-help)
           (confirm)
      )

     ((set name
           (askchoice
                (prompt #MEorHE)
                (help #MEHEhelp)
                (choices "Middle-End library" "High End library")
                (if (patmatch (database "chiprev") "AA")
                     (default 1)
                     (default 0)
                )
           )
      )

      (if (= name 0)
           (copylib
                (source "/libs/ME/newicon.library")
                (dest "libs:")
                (prompt #install-library)
                (help #install-library-help)
                (confirm)
           )



           (copylib
                (source "/libs/HE/newicon.library")
                (dest "libs:")
                (prompt #install-library)
                (help #install-library-help)
                (confirm)
           )
      )
     )
   )


;--------------------------------------------------------
; Install NewIcons and support files
;--------------------------------------------------------

(complete 20)
(if (BITAND InstallOpt 1)

  ((copylib
      (prompt #install-newicons)
      (source "/C/NewIcons")
      (dest "c:")
      (help #install-newicons-help)
   )

   (copylib
      (source "/C/InjectBrush")
      (dest "c:")
   )

   (copylib
      (source "/C/PatchOpenWB")
      (dest "c:")
   )

   (copylib
      (source "/C/ShowNI")
      (dest "c:")
   )


   (complete 30)

   (set destdir
      (askdir
            (prompt #tools-dest)
            (help @askdir-help)
            (default "Sys:Utilities")
      )
   )

   (copyfiles
      (source "/Utilities/CopyNewIcon")
      (dest destdir)
      (infos)
   )

   (copyfiles
      (source "/Utilities/CreateDefaultIcon")
      (dest destdir)
      (infos)
   )

   (copyfiles
      (source "/Utilities/KillNewIcon")
      (dest destdir)
      (infos)
   )

   (copyfiles
      (source "/Utilities/UpdateDrawers")
      (dest destdir)
      (infos)
   )


   (complete 35)
   (if (OR (AND (= NIon 0) (<> (getversion "newicon.library" (resident)) (* 39 65536))) (= NIon 5))
         ((startup "NewIcons"
            (prompt #startup-change)
            (command "Run <NIL: >NIL: c:NewIcons")
            (help @startup-help)
          )
         )
   )
   (complete 40)

   (copylib
      (prompt #install-prefs)
      (source "/prefs/NewIconsPrefs")
      (dest "Sys:prefs")
      (help #install-prefs-help)
      (confirm)
      (infos)
   )

   (run "/prefs/convertprefs")

  )
)

;------------------------------
;Install Icons
;------------------------------
(complete 50)
(if (BITAND InstallOpt 4)
  ((set looper
        (askbool
             (prompt #installdrawers)
             (help #insdraw-help)
             (choices "Yes" "No")
        )
   )
        (while (= looper 1)
             (set destdir
                (askdir
                    (prompt #selectdir)
                    (help #seldirhelp)
                    (disk)
                    (default "")
                )
             )
;             (set dirimage
                (run (cat "/Utilities/UpdateDrawers `/C/ShowNI SELECT drawers/d1.info drawers/d2.info drawers/d3.info drawers/d4.info drawers/d5.info drawers/d6.info`" " "destdir)(safe))
;             )
;             (working "Updating drawers...")
;             (run (cat "/Utilities/UpdateDrawers drawers/"dirimage " " destdir) (safe))
             (set looper
                (askbool
                    (prompt #moredrawers)
                    (help #moredraw-help)
                    (choices "Yes" "No")
                )
             )
        )

   (set looper 0)
   ((set looper
        (askbool
             (prompt #installdisk)
             (help #insdisk-help)
             (choices "Yes" "No")
        )
    )
        (while (= looper 1)
             (set destdisk
                (askdir
                    (prompt #selectdisk)
                    (help #seldiskhelp)
                    (disk)
                    (default "SYS:")
                )
             )
             (run (cat "/Utilities/CopyNewIcon `/C/ShowNI SELECT disks/d1.info disks/d2.info disks/d3.info disks/d4.info disks/d5.info disks/d6.info disks/d7.info disks/d8.info`" " "destdisk"disk.info")(safe))
             (set looper
                (askbool
                    (prompt #moredisks)
                    (help #moredisk-help)
                    (choices "Yes" "No")
                )
             )
        )
   )

     (message #install-icons)
        (if (AND (= NIon 0) (<> (getversion "newicon.library" (resident)) (* 39 65536)))
	  (run "run <NIL: >NIL: /c/NewIcons")
        )
        (working "Installing the icon set...patience.")
        (execute "Install_Icons"
        (help #install-icons-help)
     )


  )
)

;------------------------------
;Install Deficons
;------------------------------
(complete 70)
(if (BITAND InstallOpt 2)


  ((set destdir
      (askdir
           (prompt #move-olddefs-dir)
           (help #move-olddefs-help)
           (default "Sys:Storage")
      )
   )

   (set destdir
      (tackon destdir "Old_Def_icons")
   )

   (makedir destdir
   )

   (complete 80)

   (copyfiles
      (prompt #move-olddefs)
      (source "Envarc:sys")
      (dest destdir)
      (pattern "def#?")
      (help #move-olddefs-help)
   )

   (copylib
      (prompt #install-deficons)
      (source "/C/DefIcons")
      (dest "C:")
      (help #install-deficons-help)
      (confirm)
   )

   (copyfiles
      (prompt #install-envarc)
      (source "/envarc")
      (dest "ENVARC:")
      (all)
      (infos)
      (help #install-envarc-help)
   )

   (startup "DefIcons"
      (prompt #startup-deficons)
      (command "DefIcons")
      (help @startup-help)
   )
  )
)


;------------------------------
;Install Documentation
;------------------------------
(complete 90)
(if (BITAND InstallOpt 8)

   ((set destdir
      (askdir
            (prompt #docs-dest)
            (help @askdir-help)
            (default "Help:")
      )
    )
    (copyfiles
      (source "/NewIcons.guide")
      (dest destdir)
      (infos)
    )
   )
)

;------------------------------
;Install Developer Data
;------------------------------
(complete 95)
(if (BITAND InstallOpt 16)
   ((set destdir
        (askdir
            (prompt #incdir)
            (help @askdir-help)
            (default "include:")
        )
    )
    (copyfiles
        (source "/Developers/Include")
        (dest destdir)
        (all)
    )
    ((set destdir
        (askdir
            (prompt #srcdir)
            (help @askdir-help)
            (default "Work:")
        )
     )
    )
    (copyfiles
        (source "/Developers/Source")
        (dest destdir)
        (all)
    )
    ((set destdir
        (askdir
            (prompt #autoddir)
            (help @askdir-help)
            (default "Work:")
        )
     )
    )
    (copyfiles
        (source "/Developers/Autodocs")
        (dest destdir)
        (all)
    )
    (if (exists "EModules:" (noreq))
       ((set destdir
           (askdir
               (prompt #emoddir)
               (help @askdir-help)
               (default "Emodules:")
           )
        )
       (copyfiles
           (source "/Developers/Emodules")
           (dest destdir)
           (all)
       )
      )
    )
   )
)


(complete 99)
(message #powb-message (all))
(complete 100)
(message #exit-message (all))
(exit (quiet))